code\:
func void ZS_BalinWait ()
{
  PrintDebugNpc (PD_TA_FRAME, "ZS_BalinWait");
                // Debugausgaben, die man sich im Spy anzeigen lassen kann

  Npc_PercEnable(self, PERC_ASSESSPLAYER,  B_AssessSC);
                // führt unter anderem dazu, dass der Nsc bei Annäherung des Spielers
                // kontrolliert ob er eine Info hat, die ihm zum Ansprechen des Spielers
                // veranlasst (Info wird später erstellt)
  Npc_PercEnable(self, PERC_ASSESSTALK, B_AssessTalk);
                // macht den Nsc ansprechbar, damit der Spieler auch den Auftrag beenden kann

  AI_StandUp  (self);
  AI_SetWalkmode  (self, NPC_WALK);   // Walkmode für den Zustand, in diesem Fall gehen
  AI_GotoWP  (self, self.wp);   // Gehe zum Tagesablaufstart
  AI_AlignToWP (self);   // Ausrichten am WP (Pfeilrichtung im Spacer)
};

func void ZS_BalinWait_Loop ()
{
  PrintDebugNpc (PD_TA_LOOP, "ZS_BalinWait_Loop"); // s.o.
  AI_GotoWP (self, self.wp);   // Gehe zum Tagesablaufstart
  AI_PlayAni(self,  "t_pray_random");
  AI_Wait   (self, 100); // 100 Sekunden warten, bis die Loop beendet wird
};

func void ZS_BalinWait_End ()
{
  PrintDebugNpc (PD_TA_FRAME,"ZS_BalinWait_End"); // s.o.
};

code\:
func void TA_BalinWait	(var int start_h, var int start_m, var int stop_h,
 var int stop_m, VAR string waypoint) 
{TA_Min		(self,  start_h,start_m, stop_h, stop_m, ZS_BalinWait, waypoint);};

code\:
func VOID STARTUP_BKloster2 ()
{
	Wld_InsertNpc				(Kdf_2001_Balin,"Waypoint_test_01");
};
func VOID INIT_BKloster2 ()
{
	B_InitMonsterAttitudes ();
	B_InitGuildAttitudes ();
};

code\:
func void Rtn_Start_2001 ()
{
   TA_BalinWait (0,00,13,00, "Waypoint_test_01");
   TA_BalinWait (13,00,0,00, "Waypoint_test_01");

};